6.10 Quadratic Optimization

MOSEK can solve quadratic and quadratically constrained problems, as long as they are convex. This class of problems can be formulated as follows:

(6.40)$$\begin{array}{r}\begin{array}{lrcccll}\text{minimize}& & & \frac{1}{2}{x}^T{Q}^{o}x+c^{T}x+c^f& & & \\ \text{subject to}& l_k^c& \le & \frac{1}{2}{x}^T{Q}^{k}x+\sum _{j=0}^{n-1}{a}_{k,j}{x}_j& \le & u_k^c,& k=0,\dots ,m-1,\\ & l_j^x& \le & x_j& \le & u_j^x,& j=0,\dots ,n-1.\end{array}\end{array}$$

Without loss of generality it is assumed that $Q^o$ and $Q^k$ are all symmetric because

$$x^{T}Qx=\frac{1}{2}{x}^T(Q+Q^T)x.$$

This implies that a non-symmetric $Q$ can be replaced by the symmetric matrix $\frac{1}{2}(Q+Q^T)$.

The problem is required to be convex. More precisely, the matrix $Q^o$ must be positive semi-definite and the $k$th constraint must be of the form

(6.41)$$l_k^c\le \frac{1}{2}{x}^T{Q}^{k}x+\sum _{j=0}^{n-1}{a}_{k,j}{x}_j$$

with a negative semi-definite $Q^k$ or of the form

$$\frac{1}{2}{x}^T{Q}^{k}x+\sum _{j=0}^{n-1}{a}_{k,j}{x}_j\le u_k^c.$$

with a positive semi-definite $Q^k$. This implies that quadratic equalities are not allowed. Specifying a non-convex problem will result in an error when the optimizer is called.

A matrix is positive semidefinite if all the eigenvalues of $Q$ are nonnegative. An alternative statement of the positive semidefinite requirement is

$$x^{T}Qx\ge 0,\mathrm{\forall }x.$$

If the convexity (i.e. semidefiniteness) conditions are not met MOSEK will not produce reliable results or work at all.

6.10.1 Example: Quadratic Objective

We look at a small problem with linear constraints and quadratic objective:

(6.42)$$\begin{array}{r}\begin{array}{lll}\text{minimize}& & x_1^2+0.1x_2^2+x_3^2-x_1{x}_3-x_2\\ \text{subject to}& 1\le & x_1+x_2+x_3\\ & 0\le & x.\end{array}\end{array}$$

The matrix formulation of (6.42) has:

$$\begin{array}{r}{Q}^o=\left[\begin{array}{ccc}2& 0& -1\\ 0& 0.2& 0\\ -1& 0& 2\end{array}\right],c=\left[\begin{array}{c}0\\ -1\\ 0\end{array}\right],A=\left[\begin{array}{ccc}1& 1& 1\end{array}\right],\end{array}$$

with the bounds:

$$\begin{array}{r}{l}^c=1,u^c=\mathrm{\infty },l^x=\left[\begin{array}{c}0\\ 0\\ 0\end{array}\right]\text{ and }{u}^x=\left[\begin{array}{c}\mathrm{\infty }\\ \mathrm{\infty }\\ \mathrm{\infty }\end{array}\right]\end{array}$$

Please note the explicit $\frac{1}{2}$ in the objective function of (6.40) which implies that diagonal elements must be doubled in $Q$, i.e. $Q_{11}=2$ even though $1$ is the coefficient in front of $x_1^2$ in (6.42).

Setting up the linear part

The linear parts (constraints, variables, objective) are set up using exactly the same methods as for linear problems, and we refer to Sec. 6.1 (Linear Optimization) for all the details. The same applies to technical aspects such as defining an optimization task, retrieving the solution and so on.

Setting up the quadratic objective

The quadratic objective is specified using the function putqobj. Since $Q^o$ is symmetric only the lower triangular part of $Q^o$ is inputted. In fact entries from above the diagonal may not appear in the input.

The lower triangular part of the matrix $Q^o$ is specified using an unordered sparse triplet format (for details, see Sec. 15.1.4 (Matrix Formats)):

    # Set up and input quadratic objective
    qsubi = [ 1,   2,    3,   3   ]
    qsubj = [ 1,   2,    1,   3   ]
    qval  = [ 2.0, 0.2, -1.0, 2.0 ]

Please note that

• only non-zero elements are specified (any element not specified is 0 by definition),

• the order of the non-zero elements is insignificant, and

• only the lower triangular part should be specified.

Finally, this definition of $Q^o$ is loaded into the task:

    putqobj(task,qsubi,qsubj,qval)

Source code

Listing 6.18 Source code implementing problem (6.42). Click here to download.

using Mosek
using Printf, SparseArrays

# Define a stream printer to grab output from MOSEK

bkc   = [ MSK_BK_LO ]
blc   = [ 1.0 ]
buc   = [ Inf ]
  
bkx   = [ MSK_BK_LO, MSK_BK_LO, MSK_BK_LO ]
blx   = [ 0.0,  0.0, 0.0 ]
bux   = [ Inf,  Inf, Inf ]
numvar = length(bkx)
numcon = length(bkc)

c     = [ 0.0, -1.0, 0.0 ]
A     = sparse( [ 1, 1, 1 ], 
                [ 1, 2, 3 ], 
                [ 1.0, 1.0, 1.0 ],
                numcon, numvar )

maketask() do task
    # Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
    putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))

    # Append 'numcon' empty constraints.
    # The constraints will initially have no bounds.  
    appendcons(task,numcon)

    # Append 'numvar' variables.
    # The variables will initially be fixed at zero (x=0). 
    appendvars(task,numvar)

    # Set the linear term c_j in the objective.
    putclist(task,[1:numvar;],c)

    # Set the bounds on variable j
    # blx[j] <= x_j <= bux[j] 
    putvarboundslice(task,1,numvar+1,bkx,blx,bux)

    putacolslice(task,1,numvar+1,
                 A.colptr[1:numvar],A.colptr[2:numvar+1],
                 A.rowval,A.nzval)

    # Set up and input quadratic objective
    qsubi = [ 1,   2,    3,   3   ]
    qsubj = [ 1,   2,    1,   3   ]
    qval  = [ 2.0, 0.2, -1.0, 2.0 ]

    putqobj(task,qsubi,qsubj,qval)

    putobjsense(task,MSK_OBJECTIVE_SENSE_MINIMIZE)

    # Optimize
    r = optimize(task)
    # Print a summary containing information
    # about the solution for debugging purposes
    solutionsummary(task,MSK_STREAM_MSG)

    prosta = getprosta(task,MSK_SOL_ITR)
    solsta = getsolsta(task,MSK_SOL_ITR)

    if solsta == MSK_SOL_STA_OPTIMAL
        xx = getxx(task,MSK_SOL_ITR)
        println("Optimal solution:")
        println(xx)
    elseif solsta in [ MSK_SOL_STA_DUAL_INFEAS_CER,
                       MSK_SOL_STA_PRIM_INFEAS_CER ]
        println("Primal or dual infeasibility certificate found.\n")
    elseif solsta == MSK_SOL_STA_UNKNOWN
        println("Unknown solution status")
    else
        @printf("Other solution status (%d)\n",solsta)
    end

end

6.10.2 Example: Quadratic constraints

In this section we show how to solve a problem with quadratic constraints. Please note that quadratic constraints are subject to the convexity requirement (6.41).

Consider the problem:

$$\begin{array}{r}\begin{array}{lcccl}\text{minimize}& & & x_1^2+0.1x_2^2+x_3^2-x_1{x}_3-x_2& \\ \text{subject to}& 1& \le & x_1+x_2+x_3-x_1^2-x_2^2-0.1x_3^2+0.2x_1{x}_3,& \\ & & & x\ge 0.& \end{array}\end{array}$$

This is equivalent to

(6.43)$$\begin{array}{r}\begin{array}{lccl}\text{minimize}& \frac{1}{2}{x}^T{Q}^{o}x+c^{T}x& & \\ \text{subject to}& \frac{1}{2}{x}^T{Q}^{0}x+Ax& \ge & b,\\ & x\ge 0,\end{array}\end{array}$$

where

$$\begin{array}{r}{Q}^o=\left[\begin{array}{ccc}2& 0& -1\\ 0& 0.2& 0\\ -1& 0& 2\end{array}\right],c={\left[\begin{array}{ccc}0& -1& 0\end{array}\right]}^T,A=\left[\begin{array}{ccc}1& 1& 1\end{array}\right],b=1.\end{array}$$

$$\begin{array}{r}{Q}^0=\left[\begin{array}{ccc}-2& 0& 0.2\\ 0& -2& 0\\ 0.2& 0& -0.2\end{array}\right].\end{array}$$

The linear parts and quadratic objective are set up the way described in the previous tutorial.

Setting up quadratic constraints

To add quadratic terms to the constraints we use the function putqconk.

    qsubi = [  1,    2,    3,   3   ]
    qsubj = [  1,    2,    3,   1   ]
    qval  = [ -2.0, -2.0, -0.2, 0.2 ]

    # put Q^0 in constraint with index 0. 

    putqconk(task,1, qsubi,qsubj, qval) 

While putqconk adds quadratic terms to a specific constraint, it is also possible to input all quadratic terms in one chunk using the putqcon function.

Source code

Listing 6.19 Implementation of the quadratically constrained problem (6.43). Click here to download.

using Mosek
using Printf
# Since the actual value of Infinity is ignores, we define it solely
# for symbolic purposes:


# Set up and input bounds and linear coefficients
bkc   = [ MSK_BK_LO ]
blc   = [ 1.0 ]
buc   = [ Inf ]
  
bkx   = [ MSK_BK_LO
          MSK_BK_LO
          MSK_BK_LO ]
blx   = [ 0.0,  0.0, 0.0 ]
bux   = [ Inf,  Inf, Inf ]

c     = [ 0.0, -1.0, 0.0 ]

asub  = [ 1 ,2, 3 ]
aval  = [ 1.0, 1.0, 1.0 ]

numvar = length(bkx)
numcon = length(bkc)


# Create a task
maketask() do task
    # Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
    # Append 'numcon' empty constraints.
    # The constraints will initially have no bounds. 
    appendcons(task,numcon)
    
    #Append 'numvar' variables.
    # The variables will initially be fixed at zero (x=0). 
    appendvars(task,numvar)

    #Optionally add a constant term to the objective. 
    putcfix(task,0.0)
    # Set the linear term c_j in the objective.
    putclist(task,[1:numvar;],c)

    # Set the bounds on variable j
    # blx[j] <= x_j <= bux[j] 
    putvarboundslice(task,1,numvar+1,bkx,blx,bux)
    # Input column j of A 
    putarow(task,1,asub,aval)

    putconbound(task,1,bkc[1],blc[1],buc[1])
    
    # Set up and input quadratic objective

    qsubi = [ 1,   2,    3,   3   ]
    qsubj = [ 1,   2,    1,   3   ]
    qval  = [ 2.0, 0.2, -1.0, 2.0 ]

    putqobj(task,qsubi,qsubj,qval)

    # The lower triangular part of the Q^0
    # matrix in the first constraint is specified.
    # This corresponds to adding the term
    # - x0^2 - x1^2 - 0.1 x2^2 + 0.2 x0 x2

    qsubi = [  1,    2,    3,   3   ]
    qsubj = [  1,    2,    3,   1   ]
    qval  = [ -2.0, -2.0, -0.2, 0.2 ]

    # put Q^0 in constraint with index 0. 

    putqconk(task,1, qsubi,qsubj, qval) 

    # Input the objective sense (minimize/maximize)
    putobjsense(task,MSK_OBJECTIVE_SENSE_MINIMIZE)

    # Optimize the task
    optimize(task)
    # Print a summary containing information
    # about the solution for debugging purposes
    solutionsummary(task,MSK_STREAM_MSG)
    prosta = getprosta(task,MSK_SOL_ITR)
    solsta = getsolsta(task,MSK_SOL_ITR)

    if solsta == MSK_SOL_STA_OPTIMAL
        # Output a solution
        xx = getxx(task,MSK_SOL_ITR)
        @printf("Optimal solution: %s\n", xx')
    elseif solsta == MSK_SOL_STA_DUAL_INFEAS_CER
        println("Primal or dual infeasibility.\n")
    elseif solsta == MSK_SOL_STA_PRIM_INFEAS_CER
        println("Primal or dual infeasibility.\n")
    elseif solsta == MSK_SOL_STA_UNKNOWN
        println("Unknown solution status")
    else
        println("Other solution status")
    end
end