6.4 Power Cone Optimization

The structure of a typical conic optimization problem is

$$\begin{array}{r}\begin{array}{lccccl}\text{minimize}& & & c^{T}x+c^f& & \\ \text{subject to}& l^c& \le & Ax& \le & u^c,\\ & l^x& \le & x& \le & u^x,\\ & & & Fx+g& \in & \mathcal{D},\end{array}\end{array}$$

(see Sec. 12 (Problem Formulation and Solutions) for detailed formulations). Here we discuss how to set-up problems with the primal/dual power cones.

MOSEK supports the primal and dual power cones, defined as below:

• Primal power cone:

  $${\mathcal{P}}_n^{{\alpha }_k}=\{x\in {\mathbb{R}}^n:\prod _{i=0}^{n_{\ell }-1}{x}_i^{{\beta }_i}\ge \sqrt{\sum _{j=n_{\ell }}^{n-1}{x}_j^2},x_0\dots ,x_{n_{\ell }-1}\ge 0\}$$

  where $s=\sum _i{\alpha }_i$ and ${\beta }_i={\alpha }_i/s$, so that $\sum _i{\beta }_i=1$.

• Dual power cone:

  $$({\mathcal{P}}_n^{{\alpha }_k})=\{x\in {\mathbb{R}}^n:\prod _{i=0}^{n_{\ell }-1}{\left(\frac{x_i}{{\beta }_i}\right)}^{{\beta }_i}\ge \sqrt{\sum _{j=n_{\ell }}^{n-1}{x}_j^2},x_0\dots ,x_{n_{\ell }-1}\ge 0\}$$

  where $s=\sum _i{\alpha }_i$ and ${\beta }_i={\alpha }_i/s$, so that $\sum _i{\beta }_i=1$.

Perhaps the most important special case is the three-dimensional power cone family:

$${\mathcal{P}}_3^{\alpha ,1-\alpha }=\{x\in {\mathbb{R}}^3:x_0^{\alpha }{x}_1^{1-\alpha }\ge |x_2|,x_0,x_1\ge 0\}.$$

which has the corresponding dual cone:

For example, the conic constraint $(x,y,z)\in {\mathcal{P}}_3^{0.25,0.75}$ is equivalent to $x^{0.25}{y}^{0.75}\ge |z|$, or simply $x{y}^3\ge z^4$ with $x,y\ge 0$.

For other types of cones supported by MOSEK, see Sec. 15.8 (Supported domains) and the other tutorials in this chapter. Different cone types can appear together in one optimization problem.

6.4.1 Example POW1

Consider the following optimization problem which involves powers of variables:

(6.12)$$\begin{array}{r}\begin{array}{lrcl}\text{maximize}& x_0^{0.2}{x}_1^{0.8}+x_2^{0.4}-x_0& & \\ \text{subject to}& x_0+x_1+\frac{1}{2}{x}_2& =& 2,\\ & x_0,x_1,x_2& \ge & 0.\end{array}\end{array}$$

We convert (6.12) into affine conic form using auxiliary variables as bounds for the power expressions:

(6.13)$$\begin{array}{r}\begin{array}{lrcl}\text{maximize}& x_3+x_4-x_0& & \\ \text{subject to}& x_0+x_1+\frac{1}{2}{x}_2& =& 2,\\ & (x_0,x_1,x_3)& \in & {\mathcal{P}}_3^{0.2,0.8},\\ & (x_2,1.0,x_4)& \in & {\mathcal{P}}_3^{0.4,0.6}.\end{array}\end{array}$$

The two conic constraints shown in (6.13) can be expressed in the ACC form as shown in (6.14):

(6.14)$$\begin{array}{r}\left[\begin{array}{ccccc}1& 0& 0& 0& 0\\ 0& 1& 0& 0& 0\\ 0& 0& 0& 1& 0\\ 0& 0& 1& 0& 0\\ 0& 0& 0& 0& 0\\ 0& 0& 0& 0& 1\end{array}\right]\left[\begin{array}{c}{x}_0\\ x_1\\ x_2\\ x_3\\ x_4\end{array}\right]+\left[\begin{array}{c}0\\ 0\\ 0\\ 0\\ 1\\ 0\end{array}\right]\in {\mathcal{P}}_3^{0.2,0.8}\times {\mathcal{P}}_3^{0.4,0.6}.\end{array}$$

Setting up the linear part

The linear parts (constraints, variables, objective) are set up using exactly the same methods as for linear problems, and we refer to Sec. 6.1 (Linear Optimization) for all the details. The same applies to technical aspects such as defining an optimization task, retrieving the solution and so on.

Setting up the conic constraints

In order to append the conic constraints we first input the matrix $\mathbf{F}$ and vector $\mathbf{g}$ which together determine all the six affine expressions appearing in the conic constraints of (6.13)

    # Input the cones
    pc1 = appendprimalpowerconedomain(task,3,[0.2, 0.8])
    pc2 = appendprimalpowerconedomain(task,3,[4.0, 6.0])

    appendafes(task,6)
    putafefentrylist(task,
                     [1, 2, 3, 4, 6], # Rows
                     [1, 2, 4, 3, 5],  #Columns
                     [1.0, 1.0, 1.0, 1.0, 1.0])
    putafeg(task,5,1.0)

    # Append the two conic constraints
    appendacc(task,
              pc1,           # Domain
              [1, 2, 3],     # Rows from F
              nothing)
    appendacc(task,
              pc2,           # Domain
              [4, 5, 6],     # Rows from F
              nothing)

Following that, each of the affine conic constraints is appended using the function appendacc. The first argument selects the domain, which must be appended before being used, and must have the dimension matching the number of affine expressions appearing in the constraint. In the first case we append the power cone determined by the first three rows of $\mathbf{F}$ and $\mathbf{g}$ while in the second call we use the remaining three rows of $\mathbf{F}$ and $\mathbf{g}$.

Variants of this method are available to append multiple ACCs at a time. It is also possible to define the matrix $\mathbf{F}$ using a variety of methods (row after row, column by column, individual entries, etc.) similarly as for the linear constraint matrix $A$.

For a more thorough exposition of the affine expression storage (AFE) matrix $\mathbf{F}$ and vector $\mathbf{g}$ see Sec. 6.2 (From Linear to Conic Optimization).

Source code

Listing 6.5 Source code solving problem (6.12). Click here to download.

using Mosek
printstream(msg::AbstractString) = print(msg)


csub = [ 4, 5, 1 ]
cval = [ 1.0, 1.0, -1.0]
asub = [ 1, 2, 3]
aval = [ 1.0, 1.0, 0.5]
numvar = 5
numcon = 1

# Create a task
maketask() do task
    # Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
    putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))

    appendcons(task,numcon)
    appendvars(task,numvar)

    # Set up the linear part of the problem
    putclist(task,csub, cval)
    putarow(task,1, asub, aval)
    putconbound(task,1, MSK_BK_FX, 2.0, 2.0)

    putvarboundsliceconst(task,1, numvar+1,MSK_BK_FR,-Inf,Inf)

    # Input the cones
    pc1 = appendprimalpowerconedomain(task,3,[0.2, 0.8])
    pc2 = appendprimalpowerconedomain(task,3,[4.0, 6.0])

    appendafes(task,6)
    putafefentrylist(task,
                     [1, 2, 3, 4, 6], # Rows
                     [1, 2, 4, 3, 5],  #Columns
                     [1.0, 1.0, 1.0, 1.0, 1.0])
    putafeg(task,5,1.0)

    # Append the two conic constraints
    appendacc(task,
              pc1,           # Domain
              [1, 2, 3],     # Rows from F
              nothing)
    appendacc(task,
              pc2,           # Domain
              [4, 5, 6],     # Rows from F
              nothing)

    # Input the objective sense (minimize/maximize)
    putobjsense(task,MSK_OBJECTIVE_SENSE_MAXIMIZE)

    # Optimize the task
    optimize(task)
    writedata(task,"pow1.ptf")
    # Print a summary containing information
    # about the solution for debugging purposes
    solutionsummary(task,MSK_STREAM_MSG)
    prosta = getprosta(task,MSK_SOL_ITR)
    solsta = getsolsta(task,MSK_SOL_ITR)

    if solsta == MSK_SOL_STA_OPTIMAL
        # Output a solution
        xx = getxx(task,MSK_SOL_ITR)
        println("Optimal solution: $(xx[1:3])")
    elseif solsta == MSK_SOL_STA_DUAL_INFEAS_CER
        println("Primal or dual infeasibility.")
    elseif solsta == MSK_SOL_STA_PRIM_INFEAS_CER
        println("Primal or dual infeasibility.")
    elseif solsta == MSK_SOL_STA_UNKNOWN
        println("Unknown solution status")
    else
        println("Other solution status")
    end
end