6.3 Conic Quadratic Optimization¶
The structure of a typical conic optimization problem is
(see Sec. 12 (Problem Formulation and Solutions) for detailed formulations). We recommend Sec. 6.2 (From Linear to Conic Optimization) for a tutorial on how problems of that form are represented in MOSEK and what data structures are relevant. Here we discuss how to set-up problems with the (rotated) quadratic cones.
MOSEK supports two types of quadratic cones, namely:
Quadratic cone:
\[\Q^n = \left\lbrace x \in \real^n: x_0 \geq \sqrt{\sum_{j=1}^{n-1} x_j^2} \right\rbrace.\]Rotated quadratic cone:
\[\Qr^n = \left\lbrace x \in \real^n: 2 x_0 x_1 \geq \sum_{j=2}^{n-1} x_j^2,\quad x_0\geq 0,\quad x_1 \geq 0 \right\rbrace.\]
For example, consider the following constraint:
which describes a convex cone in \(\real^3\) given by the inequality:
For other types of cones supported by MOSEK, see Sec. 15.8 (Supported domains) and the other tutorials in this chapter. Different cone types can appear together in one optimization problem.
6.3.1 Example CQO1¶
Consider the following conic quadratic problem which involves some linear constraints, a quadratic cone and a rotated quadratic cone.
The two conic constraints can be expressed in the ACC form as shown in (6.11)
Setting up the linear part
The linear parts (constraints, variables, objective) are set up using exactly the same methods as for linear problems, and we refer to Sec. 6.1 (Linear Optimization) for all the details. The same applies to technical aspects such as defining an optimization task, retrieving the solution and so on.
Setting up the conic constraints
In order to append the conic constraints we first input the matrix \(\afef\) and vector \(\afeg\) appearing in (6.11). The matrix \(\afef\) is sparse and we input only its nonzeros using putafefentrylist. Since \(\afeg\) is zero, nothing needs to be done about this vector.
Each of the conic constraints is appended using the function appendacc. In the first case we append the quadratic cone determined by the first three rows of \(\afef\) and then the rotated quadratic cone depending on the remaining three rows of \(\afef\).
# Input the cones
appendafes(task,6)
putafefentrylist(task,
[1, 2, 3, 4, 5, 6], # Rows
[4, 1, 2, 5, 6, 3], # Columns */
[1.0, 1.0, 1.0, 1.0, 1.0, 1.0])
# Quadratic cone (x(3),x(0),x(1)) \in QUAD_3
quadcone = appendquadraticconedomain(task,3)
appendacc(task,
quadcone, # Domain
[1, 2, 3], # Rows from F
nothing)
# Rotated quadratic cone (x(4),x(5),x(2)) \in RQUAD_3
rquadcone = appendrquadraticconedomain(task,3)
appendacc(task,
rquadcone, # Domain
[4, 5, 6], # Rows from F
nothing);
The first argument selects the domain, which must be appended before being used, and must have the dimension matching the number of affine expressions appearing in the constraint. Variants of this method are available to append multiple ACCs at a time. It is also possible to define the matrix \(\afef\) using a variety of methods (row after row, column by column, individual entries, etc.) similarly as for the linear constraint matrix \(A\).
For a more thorough exposition of the affine expression storage (AFE) matrix \(\afef\) and vector \(\afeg\) see Sec. 6.2 (From Linear to Conic Optimization).
Source code
using Mosek
printstream(msg::AbstractString) = print(msg)
callback(where,dinf,iinf,liinf) = 0
# Since the actual value of Infinity is ignores, we define it solely
# for symbolic purposes:
bkc = [ MSK_BK_FX ]
blc = [ 1.0 ]
buc = [ 1.0 ]
c = [ 0.0, 0.0, 0.0,
1.0, 1.0, 1.0 ]
bkx = [ MSK_BK_LO,MSK_BK_LO,MSK_BK_LO,
MSK_BK_FR,MSK_BK_FR,MSK_BK_FR ]
blx = [ 0.0, 0.0, 0.0,
-Inf, -Inf, -Inf ]
bux = [ Inf, Inf, Inf,
Inf, Inf, Inf ]
asub = [ 1 ,2, 3 ]
aval = [ 1.0, 1.0, 2.0 ]
numvar = length(bkx)
numcon = length(bkc)
# Create a task
maketask() do task
# Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
putstreamfunc(task,MSK_STREAM_LOG,printstream)
putcallbackfunc(task,callback)
# Append 'numcon' empty constraints.
# The constraints will initially have no bounds.
appendcons(task,numcon)
#Append 'numvar' variables.
# The variables will initially be fixed at zero (x=0).
appendvars(task,numvar)
# Set the linear term c_j in the objective.
putclist(task,[1:6;],c)
# Set the bounds on variable j
# blx[j] <= x_j <= bux[j]
putvarboundslice(task,1,numvar+1,bkx,blx,bux)
putarow(task,1,asub,aval)
putconbound(task,1,bkc[1],blc[1],buc[1])
# Input the cones
appendafes(task,6)
putafefentrylist(task,
[1, 2, 3, 4, 5, 6], # Rows
[4, 1, 2, 5, 6, 3], # Columns */
[1.0, 1.0, 1.0, 1.0, 1.0, 1.0])
# Quadratic cone (x(3),x(0),x(1)) \in QUAD_3
quadcone = appendquadraticconedomain(task,3)
appendacc(task,
quadcone, # Domain
[1, 2, 3], # Rows from F
nothing)
# Rotated quadratic cone (x(4),x(5),x(2)) \in RQUAD_3
rquadcone = appendrquadraticconedomain(task,3)
appendacc(task,
rquadcone, # Domain
[4, 5, 6], # Rows from F
nothing);
# Input the objective sense (minimize/maximize)
putobjsense(task,MSK_OBJECTIVE_SENSE_MINIMIZE)
# Optimize the task
#optimize(task,"mosek://solve.mosek.com:30080")
optimize(task)
writedata(task,"cqo1.ptf")
# Print a summary containing information
# about the solution for debugging purposes
solutionsummary(task,MSK_STREAM_MSG)
prosta = getprosta(task,MSK_SOL_ITR)
solsta = getsolsta(task,MSK_SOL_ITR)
if solsta == MSK_SOL_STA_OPTIMAL
# Output a solution
xx = getxx(task,MSK_SOL_ITR)
println("Optimal solution: $xx")
elseif solsta == MSK_SOL_STA_DUAL_INFEAS_CER
println("Primal or dual infeasibility.\n")
elseif solsta == MSK_SOL_STA_PRIM_INFEAS_CER
println("Primal or dual infeasibility.\n")
elseif solsta == MSK_SOL_STA_UNKNOWN
println("Unknown solution status")
else
println("Other solution status")
end
end
