11.1 Portfolio Optimization¶
In this section the Markowitz portfolio optimization problem and variants are implemented using Optimizer API for Julia.
Familiarity with Sec. 6.2 (From Linear to Conic Optimization) is recommended to follow the syntax used to create affine conic constraints (ACCs) throughout all the models appearing in this case study.
11.1.1 The Basic Model¶
The classical Markowitz portfolio optimization problem considers investing in \(n\) stocks or assets held over a period of time. Let \(x_j\) denote the amount invested in asset \(j\), and assume a stochastic model where the return of the assets is a random variable \(r\) with known mean
and covariance
The return of the investment is also a random variable \(y = r^Tx\) with mean (or expected return)
and variance
The standard deviation
is usually associated with risk.
The problem facing the investor is to rebalance the portfolio to achieve a good compromise between risk and expected return, e.g., maximize the expected return subject to a budget constraint and an upper bound (denoted \(\gamma\)) on the tolerable risk. This leads to the optimization problem
The variables \(x\) denote the investment i.e. \(x_j\) is the amount invested in asset \(j\) and \(x_j^0\) is the initial holding of asset \(j\). Finally, \(w\) is the initial amount of cash available.
A popular choice is \(x^0=0\) and \(w=1\) because then \(x_j\) may be interpreted as the relative amount of the total portfolio that is invested in asset \(j\).
Since \(e\) is the vector of all ones then
is the total investment. Clearly, the total amount invested must be equal to the initial wealth, which is
\[w + e^T x^0.\]
This leads to the first constraint
\[e^T x = w + e^T x^0.\]
The second constraint
\[x^T \Sigma x \leq \gamma^2\]
ensures that the variance, is bounded by the parameter \(\gamma^2\). Therefore, \(\gamma\) specifies an upper bound of the standard deviation (risk) the investor is willing to undertake. Finally, the constraint
\[x_j \geq 0\]
excludes the possibility of short-selling. This constraint can of course be excluded if short-selling is allowed.
The covariance matrix \(\Sigma\) is positive semidefinite by definition and therefore there exist a matrix \(G \in \mathbb{R}^{n\times k}\) such that
In general the choice of \(G\) is not unique and one possible choice of \(G\) is the Cholesky factorization of \(\Sigma\). However, in many cases another choice is better for efficiency reasons as discussed in Sec. 11.1.3 (Factor model and efficiency). For a given \(G\) we have that
Hence, we may write the risk constraint as
or equivalently
where \(\Q^{k+1}\) is the \((k+1)\)-dimensional quadratic cone. Note that specifically when \(G\) is derived using Cholesky factorization, \(k = n\).
Therefore, problem (11.1) can be written as
which is a conic quadratic optimization problem that can easily be formulated and solved with Optimizer API for Julia. Subsequently we will use the example data
and
Using Cholesky factorization, this implies
In Sec. 11.1.3 (Factor model and efficiency), we present a different way of obtaining \(G\) based on a factor model, that leads to more efficient computation.
Why a Conic Formulation?
Problem (11.1) is a convex quadratically constrained optimization problem that can be solved directly using MOSEK. Why then reformulate it as a conic quadratic optimization problem (11.3)? The main reason for choosing a conic model is that it is more robust and usually solves faster and more reliably. For instance it is not always easy to numerically validate that the matrix \(\Sigma\) in (11.1) is positive semidefinite due to the presence of rounding errors. It is also very easy to make a mistake so \(\Sigma\) becomes indefinite. These problems are completely eliminated in the conic formulation.
Moreover, observe the constraint
more numerically robust than
for very small and very large values of \(\gamma\). Indeed, if say \(\gamma \approx 10^4\) then \(\gamma^2\approx 10^8\), which introduces a scaling issue in the model. Hence, using conic formulation we work with the standard deviation instead of variance, which usually gives rise to a better scaled model.
Example code
Listing 11.1 demonstrates how the basic Markowitz model (11.3) is implemented.
function portfolio( mu :: Vector{Float64},
x0 :: Vector{Float64},
w :: Float64,
gamma :: Float64,
GT :: Array{Float64,2})
(k,n) = size(GT)
maketask() do task
# Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
# Directs the log task stream
putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))
totalBudget = sum(x0)+w
#Offset of variables into the API variable.
x_ofs = 0
# Constraints offsets
budget_ofs = 0
# Holding variable x of length n
# No other auxiliary variables are needed in this formulation
appendvars(task,n)
# Setting up variable x
for j in 1:n
# Optionally we can give the variables names
putvarname(task, x_ofs+j, "x[$(j)]");
# No short-selling - x^l = 0, x^u = inf
putvarbound(task,x_ofs+j, MSK_BK_LO, 0.0, Inf);
end
# One linear constraint: total budget
appendcons(task,1);
putconname(task,1,"budget");
for j in 1:n
# Coefficients in the first row of A
putaij(task,budget_ofs+1, x_ofs+j, 1.0)
end
putconbound(task, budget_ofs+1, MSK_BK_FX, totalBudget, totalBudget)
# Input (gamma, GTx) in the AFE (affine expression) storage
# We need k+1 rows
appendafes(task,k + 1)
# The first affine expression = gamma
putafeg(task,1, gamma)
# The remaining k expressions comprise GT*x, we add them row by row
# In more realisic scenarios it would be better to extract nonzeros and input in sparse form
subj = [1:n...]
for i in 1:k
putafefrow(task,i + 1, subj, GT[i,:])
end
# Input the affine conic constraint (gamma, GT*x) \in QCone
# Add the quadratic domain of dimension k+1
qdom = appendquadraticconedomain(task,k + 1)
# Add the constraint
appendaccseq(task,qdom,1,nothing)
putaccname(task,1, "risk")
# Objective: maximize expected return mu^T x
putclist(task,[x_ofs+1:x_ofs+n...],mu)
putobjsense(task,MSK_OBJECTIVE_SENSE_MAXIMIZE)
optimize(task)
# Display solution summary for quick inspection of results
solutionsummary(task,MSK_STREAM_LOG)
writedata(task,"portfolio_1_basic.ptf");
# Check if the interior point solution is an optimal point
if getsolsta(task, MSK_SOL_ITR) != MSK_SOL_STA_OPTIMAL
# See https://docs.mosek.com/latest/juliaapi/accessing-solution.html about handling solution statuses.
error("Solution not optimal")
end
# Read the results
xx = getxxslice(task,MSK_SOL_ITR, x_ofs+1,x_ofs+n+1)
expret = mu' * xx
(xx,expret)
end
end # portfolio()
The code is organized as follows:
We have \(n\) optimization variables, one per each asset in the portfolio. They correspond to the variable \(x\) from (11.1) and their indices as variables in the task are from \(0\) to \(n-1\) (inclusive).
The linear part of the problem: budget constraint, no-short-selling bounds and the objective are added in the linear data of the task (\(A\) matrix, \(c\) vector and bounds) following the techniques introduced in the tutorial of Sec. 6.1 (Linear Optimization).
For the quadratic constraint we follow the path introduced in the tutorial of Sec. 6.2 (From Linear to Conic Optimization). We add the vector \((\gamma, G^Tx)\) to the affine expression storage (AFE), create a quadratic domain of suitable length, and add the affine conic constraint (ACC) with the selected affine expressions. In the segment
# Input the affine conic constraint (gamma, GT*x) \in QCone # Add the quadratic domain of dimension k+1 qdom = appendquadraticconedomain(task,k + 1) # Add the constraint appendaccseq(task,qdom,1,nothing)
we use
appendaccseqto append a single ACC with the quadratic domainqdomand with a sequence of affine expressions starting at position \(0\) in the AFE storage and of length equal to the dimension ofqdom. This is the simplest way to achieve what we need, since previously we also stored the required rows in AFE in the same order.
11.1.2 The Efficient Frontier¶
The portfolio computed by the Markowitz model is efficient in the sense that there is no other portfolio giving a strictly higher return for the same amount of risk. An efficient portfolio is also sometimes called a Pareto optimal portfolio. Clearly, an investor should only invest in efficient portfolios and therefore it may be relevant to present the investor with all efficient portfolios so the investor can choose the portfolio that has the desired tradeoff between return and risk.
Given a nonnegative \(\alpha\) the problem
is one standard way to trade the expected return against penalizing variance. Note that, in contrast to the previous example, we explicitly use the variance (\(\|G^Tx\|_2^2\)) rather than standard deviation (\(\|G^Tx\|_2\)), therefore the conic model includes a rotated quadratic cone:
The parameter \(\alpha\) specifies the tradeoff between expected return and variance. Ideally the problem (11.4) should be solved for all values \(\alpha \geq 0\) but in practice it is impossible. Using the example data from Sec. 11.1.1 (The Basic Model), the optimal values of return and variance for several values of \(\alpha\) are shown in the figure.
Fig. 11.1 The efficient frontier for the sample data.¶
Example code
Listing 11.2 demonstrates how to compute the efficient portfolios for several values of \(\alpha\).
here to download.¶function portfolio( mu :: Vector{Float64},
x0 :: Vector{Float64},
w :: Float64,
alphas :: Vector{Float64},
GT :: Array{Float64,2})
(k,n) = size(GT)
maketask() do task
# Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
# Directs the log task stream
#putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))
totalBudget = sum(x0)+w
#Offset of variables into the API variable.
x_ofs = 0
s_ofs = n
# Constraints offsets
budget_ofs = 0
# Holding variable x of length n
# No other auxiliary variables are needed in this formulation
appendvars(task,n+1)
# Setting up variable x
for j in 1:n
# Optionally we can give the variables names
putvarname(task, x_ofs+j, "x[$(j)]")
# No short-selling - x^l = 0, x^u = inf
putvarbound(task,x_ofs+j, MSK_BK_LO, 0.0, Inf)
end
putvarname(task, s_ofs+1, "s")
putvarbound(task,s_ofs+1, MSK_BK_FR, -Inf, Inf)
# One linear constraint: total budget
appendcons(task,1)
putconname(task,1,"budget")
for j in 1:n
# Coefficients in the first row of A
putaij(task,budget_ofs+1, x_ofs+j, 1.0)
end
putconbound(task, budget_ofs+1, MSK_BK_FX, totalBudget, totalBudget)
# Input (gamma, GTx) in the AFE (affine expression) storage
# We build the following F and g for variables [x, s]:
# [0, 1] [0 ]
# F = [0, 0], g = [0.5]
# [GT,0] [0 ]
# We need k+2 rows
appendafes(task,k + 2)
# The first affine expression = alpha
putafefentry(task,1,s_ofs+1,1.0)
putafeg(task,2,0.5)
# The remaining k expressions comprise GT*x, we add them row by row
# In more realisic scenarios it would be better to extract nonzeros and input in sparse form
subj = [1:n...]
for i in 1:k
putafefrow(task,i + 2, subj, GT[i,:])
end
# Input the affine conic constraint (alpha, GT*x) \in QCone
# Add the quadratic domain of dimension k+1
qdom = appendrquadraticconedomain(task,k + 2)
# Add the constraint
appendaccseq(task,qdom,1,nothing)
putaccname(task,1, "risk")
# Objective: maximize expected return mu^T x
putclist(task,[x_ofs+1:x_ofs+n...],mu)
putobjsense(task,MSK_OBJECTIVE_SENSE_MAXIMIZE)
expret = Float64[]
stddev = Float64[]
for alpha in alphas
putcj(task,s_ofs+1,-alpha)
optimize(task)
writedata(task,"portfolio_2_frontier-$alpha.ptf")
# Check if the interior point solution is an optimal point
if getsolsta(task, MSK_SOL_ITR) != MSK_SOL_STA_OPTIMAL
# See https://docs.mosek.com/latest/juliaapi/accessing-solution.html about handling solution statuses.
error("Solution not optimal")
end
# Display solution summary for quick inspection of results
solutionsummary(task,MSK_STREAM_LOG)
# Read the results
r = mu' * getxxslice(task,MSK_SOL_ITR, x_ofs+1,x_ofs+n+1)
slvl = getxxslice(task,MSK_SOL_ITR, s_ofs+1,s_ofs+2)
push!(expret,r)
push!(stddev,sqrt(slvl[1]))
end
(expret,stddev)
end
end # portfolio()
Note that we changed the coefficient \(\alpha\) of the variable \(s\) in a loop. This way we were able to reuse the same model for all solves along the efficient frontier, simply changing the value of \(\alpha\) between the solves.
11.1.3 Factor model and efficiency¶
In practice it is often important to solve the portfolio problem very quickly. Therefore, in this section we discuss how to improve computational efficiency at the modeling stage.
The computational cost is of course to some extent dependent on the number of constraints and variables in the optimization problem. However, in practice a more important factor is the sparsity: the number of nonzeros used to represent the problem. Indeed it is often better to focus on the number of nonzeros in \(G\) see (11.2) and try to reduce that number by for instance changing the choice of \(G\).
In other words if the computational efficiency should be improved then it is always good idea to start with focusing at the covariance matrix. As an example assume that
where \(D\) is a positive definite diagonal matrix. Moreover, \(V\) is a matrix with \(n\) rows and \(k\) columns. Such a model for the covariance matrix is called a factor model and usually \(k\) is much smaller than \(n\). In practice \(k\) tends to be a small number independent of \(n\), say less than 100.
One possible choice for \(G\) is the Cholesky factorization of \(\Sigma\) which requires storage proportional to \(n(n+1)/2\). However, another choice is
because then
This choice requires storage proportional to \(n+kn\) which is much less than for the Cholesky choice of \(G\). Indeed assuming \(k\) is a constant storage requirements are reduced by a factor of \(n\).
The example above exploits the so-called factor structure and demonstrates that an alternative choice of \(G\) may lead to a significant reduction in the amount of storage used to represent the problem. This will in most cases also lead to a significant reduction in the solution time.
The lesson to be learned is that it is important to investigate how the covariance matrix is formed. Given this knowledge it might be possible to make a special choice for \(G\) that helps reducing the storage requirements and enhance the computational efficiency. More details about this process can be found in [And13].
Factor model in finance
Factor model structure is typical in financial context. It is common to model security returns as the sum of two components using a factor model. The first component is the linear combination of a small number of factors common among a group of securities. The second component is a residual, specific to each security. It can be written as \(R = \sum_j\beta_j F_j + \theta\), where \(R\) is a random variable representing the return of a security at a particular point in time, \(F_j\) is the random variable representing the common factor \(j\), \(\beta_j\) is the exposure of the return to factor \(j\), and \(\theta\) is the specific component.
Such a model will result in the covariance structure
where \(\Sigma_F\) is the covariance of the factors and \(\Sigma_\theta\) is the residual covariance. This structure is of the form discussed earlier with \(D = \Sigma_\theta\) and \(V = \beta P\), assuming the decomposition \(\Sigma_F = PP^T\). If the number of factors \(k\) is low and \(\Sigma_\theta\) is diagonal, we get a very sparse \(G\) that provides the storage and solution time benefits.
Example code
Here we will work with the example data of a two-factor model (\(k=2\)) built using the variables
and the factor covariance matrix is
giving
Then the matrix \(G\) would look like
This matrix is indeed very sparse.
In general, we get an \(n\times (n+k)\) size matrix this way with \(k\) full columns and an \(n\times n\) diagonal part. In order to maintain a sparse representation we do not construct the matrix \(G\) explicitly in the code but instead work with two pieces of data: the dense matrix \(G_\mathrm{factor} = \beta P\) of shape \(n\times k\) and the diagonal vector \(\theta\) of length \(n\).
Example code
In the following we demonstrate how to write code to compute the matrix \(G_\mathrm{factor}\) of the factor model. We start with the inputs
# Factor exposure matrix, n x 2
B = [ 0.4256 0.1869
0.2413 0.3877
0.2235 0.3697
0.1503 0.4612
1.5325 -0.2633
1.2741 -0.2613
0.6939 0.2372
0.5425 0.2116 ],
# Factor covariance matrix, 2x2
S_F = [ 0.0620 0.0577
0.0577 0.0908 ],
# Specific risk components
theta = [0.0720, 0.0508, 0.0377, 0.0394, 0.0663, 0.0224, 0.0417, 0.0459],
S_sqrt_theta = Matrix(Diagonal(sqrt.(theta))),
Then the matrix \(G_\mathrm{factor}\) is obtained as:
P = Matrix(cholesky(S_F).L),
BP = B * P,
G = [ BP S_sqrt_theta ],
GT = Matrix(G') # 10 x 8
The code for computing an optimal portfolio in the factor model is very similar to the one from the basic model in Listing 11.1 with one notable exception: we construct the expression \(G^Tx\) appearing in the conic constraint by stacking together two separate vectors \(G_\mathrm{factor}^T x\) and \(\Sigma^{1/2}_\theta x\):
# Input (gamma, G_factor_T x, diag(sqrt(theta))*x) in the AFE (affine expression) storage
# We need k+n+1 rows and we fill them in in three parts
appendafes(task,n+k+1)
# 1. The first affine expression = gamma, will be specified later
# 2. The next k expressions comprise G_factor_T*x, we add them row by row
# transposing the matrix G_factor on the fly
subj = [1:n...]
for i in 1:k
putafefrow(task,i + 1, subj, GT[i,:])
end
# 3. The remaining n rows contain sqrt(theta) on the diagonal
for i in 1:n
putafefentry(task,k + 1 + i, subj[i], sqrt(theta[i]))
end
The full code is demonstrated below:
function portfolio( mu :: Vector{Float64},
x0 :: Vector{Float64},
w :: Float64,
gammas :: Vector{Float64},
theta :: Vector{Float64},
GT :: Array{Float64,2})
(k,n) = size(GT)
maketask() do task
# Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
# Directs the log task stream
putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))
totalBudget = sum(x0)+w
#Offset of variables into the API variable.
x_ofs = 0
# Constraints offsets
budget_ofs = 0
# Holding variable x of length n
# No other auxiliary variables are needed in this formulation
appendvars(task,n)
# Setting up variable x
for j in 1:n
# Optionally we can give the variables names
putvarname(task, x_ofs+j, "x[$(j)]");
# No short-selling - x^l = 0, x^u = inf
putvarbound(task,x_ofs+j, MSK_BK_LO, 0.0, Inf);
end
# One linear constraint: total budget
appendcons(task,1);
putconname(task,1,"budget");
for j in 1:n
# Coefficients in the first row of A
putaij(task,budget_ofs+1, x_ofs+j, 1.0)
end
putconbound(task, budget_ofs+1, MSK_BK_FX, totalBudget, totalBudget)
# Input (gamma, G_factor_T x, diag(sqrt(theta))*x) in the AFE (affine expression) storage
# We need k+n+1 rows and we fill them in in three parts
appendafes(task,n+k+1)
# 1. The first affine expression = gamma, will be specified later
# 2. The next k expressions comprise G_factor_T*x, we add them row by row
# transposing the matrix G_factor on the fly
subj = [1:n...]
for i in 1:k
putafefrow(task,i + 1, subj, GT[i,:])
end
# 3. The remaining n rows contain sqrt(theta) on the diagonal
for i in 1:n
putafefentry(task,k + 1 + i, subj[i], sqrt(theta[i]))
end
# Input the affine conic constraint (gamma, GT*x) \in QCone
# Add the quadratic domain of dimension k+1
qdom = appendquadraticconedomain(task,n + k + 1)
# Add the constraint
appendaccseq(task,qdom,1,nothing)
putaccname(task,1, "risk")
# Objective: maximize expected return mu^T x
putclist(task,[x_ofs+1:x_ofs+n...],mu)
putobjsense(task,MSK_OBJECTIVE_SENSE_MAXIMIZE)
res = Tuple{Float64,Float64}[]
for gamma in gammas
putafeg(task,1, gamma)
optimize(task)
if getsolsta(task, MSK_SOL_ITR) != MSK_SOL_STA_OPTIMAL
# See https://docs.mosek.com/latest/juliaapi/accessing-solution.html about handling solution statuses.
error("Solution not optimal")
end
writedata(task,"portfolio_6_factor-$(gamma).ptf");
# Read the results
xx = getxxslice(task,MSK_SOL_ITR, x_ofs+1,x_ofs+n+1)
expret = mu' * xx
push!(res,(gamma,expret))
end
res
end
end # portfolio()
11.1.4 Slippage Cost¶
The basic Markowitz model assumes that there are no costs associated with trading the assets and that the returns of the assets are independent of the amount traded. Neither of those assumptions is usually valid in practice. Therefore, a more realistic model is
Here \(\Delta x_j\) is the change in the holding of asset \(j\) i.e.
and \(T_j(\Delta x_j)\) specifies the transaction costs when the holding of asset \(j\) is changed from its initial value. In the next two sections we show two different variants of this problem with two nonlinear cost functions \(T\).
11.1.5 Market Impact Costs¶
If the initial wealth is fairly small and no short selling is allowed, then the holdings will be small and the traded amount of each asset must also be small. Therefore, it is reasonable to assume that the prices of the assets are independent of the amount traded. However, if a large volume of an asset is sold or purchased, the price, and hence return, can be expected to change. This effect is called market impact costs. It is common to assume that the market impact cost for asset \(j\) can be modeled by
where \(m_j\) is a constant that is estimated in some way by the trader. See [GK00] [p. 452] for details. From the Modeling Cookbook we know that \(t \geq |z|^{3/2}\) can be modeled directly using the power cone \(\POW_3^{2/3,1/3}\):
Hence, it follows that \(\sum_{j=1}^n T_j(\Delta x_j)=\sum_{j=1}^n m_j|x_j-x_j^0|^{3/2}\) can be modeled by \(\sum_{j=1}^n m_jt_j\) under the constraints
Unfortunately this set of constraints is nonconvex due to the constraint
but in many cases the constraint may be replaced by the relaxed constraint
For instance if the universe of assets contains a risk free asset then
cannot hold for an optimal solution.
If the optimal solution has the property (11.9) then the market impact cost within the model is larger than the true market impact cost and hence money are essentially considered garbage and removed by generating transaction costs. This may happen if a portfolio with very small risk is requested because the only way to obtain a small risk is to get rid of some of the assets by generating transaction costs. We generally assume that this is not the case and hence the models (11.7) and (11.8) are equivalent.
The above observations lead to
The revised budget constraint
specifies that the initial wealth covers the investment and the transaction costs. It should be mentioned that transaction costs of the form
where \(p>1\) is a real number can be modeled with the power cone as
See the Modeling Cookbook for details.
Example code
Listing 11.5 demonstrates how to compute an optimal portfolio when market impact cost are included.
function portfolio( mu :: Vector{Float64},
x0 :: Vector{Float64},
w :: Float64,
gamma :: Float64,
GT :: Array{Float64,2},
m :: Vector{Float64})
(k,n) = size(GT)
maketask() do task
# Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
# Directs the log task stream
putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))
totalBudget = sum(x0)+w
#Offset of variables into the API variable.
x_ofs = 0
c_ofs = n
z_ofs = 2*n
# Constraints offsets
budget_ofs = 0
# Holding variable x of length n
# No other auxiliary variables are needed in this formulation
appendvars(task,3*n)
# Setting up variable x
for j in 1:n
# Optionally we can give the variables names
putvarname(task, x_ofs+j, "x[$(j)]");
putvarname(task, c_ofs+j, "c[$(j)]");
putvarname(task, z_ofs+j, "z[$(j)]");
end
# No short-selling - x^l = 0, x^u = inf
putvarboundsliceconst(task,x_ofs+1,x_ofs+n+1, MSK_BK_LO, 0.0, Inf);
putvarboundsliceconst(task,c_ofs+1,c_ofs+n+1, MSK_BK_FR, -Inf, Inf);
putvarboundsliceconst(task,z_ofs+1,z_ofs+n+1, MSK_BK_FR, -Inf, Inf);
# Linear constraint: total budget
let budget_ofs = getnumcon(task)
appendcons(task,1);
putconname(task,1,"budget");
for j in 1:n
# Coefficients in the first row of A
putaij(task,budget_ofs+1, x_ofs+j, 1.0)
putaij(task,budget_ofs+1, c_ofs+j, m[j])
end
end
putconbound(task, budget_ofs+1, MSK_BK_FX, totalBudget, totalBudget)
# - Absolute value
let zabs1_ofs = getnumcon(task),
zabs2_ofs = zabs1_ofs+n
appendcons(task,2*n)
for i in 1:n
putconname(task,zabs1_ofs + i, "zabs1[$i]")
putaij(task,zabs1_ofs + i, x_ofs + i, -1.0)
putaij(task,zabs1_ofs + i, z_ofs + i, 1.0)
putconbound(task,zabs1_ofs + i, MSK_BK_LO, -x0[i], Inf)
putconname(task,zabs2_ofs + i, "zabs2[$i]")
putaij(task,zabs2_ofs + i, x_ofs + i, 1.0)
putaij(task,zabs2_ofs + i, z_ofs + i, 1.0)
putconbound(task,zabs2_ofs + i, MSK_BK_LO, x0[i], Inf)
end
end
let qdom = appendquadraticconedomain(task,k + 1)
afei = getnumafe(task)
acci = getnumacc(task)
# Input (gamma, GTx) in the AFE (affine expression) storage
# We need k+1 rows
appendafes(task,k + 1)
# The first affine expression = gamma
putafeg(task,afei+1, gamma)
# The remaining k expressions comprise GT*x, we add them row by row
# In more realisic scenarios it would be better to extract nonzeros and input in sparse form
subj = [1:n...]
for i in 1:k
putafefrow(task,afei+i+1, subj, GT[i,:])
end
# Input the affine conic constraint (gamma, GT*x) \in QCone
# Add the quadratic domain of dimension k+1
# Add the constraint
appendaccseq(task,qdom,1,nothing)
putaccname(task,acci+1, "risk")
end
let dom = appendprimalpowerconedomain(task,3,[2.0,1.0])
afei = getnumafe(task)
acci = getnumacc(task)
afe0 = afei
appendafes(task,2*n+1)
putafeg(task,afe0+1,1.0)
afei += 1
for i in 1:n
putafefentry(task,afei + i, c_ofs + i, 1.0);
putafefentry(task,afei + n + i, z_ofs + i, 1.0);
end
accafes = Int64[ k for i in 1:n for k in [ afei + i, afe0+1, afei + n + i ] ]
accb = zeros(n*3)
accdom = Int64[ dom for i in 1:n ]
appendaccs(task,accdom,accafes,accb)
for i in 1:n
putaccname(task,acci+i,"market_impact[$i]")
end
end
# Objective: maximize expected return mu^T x
putclist(task,[x_ofs+1:x_ofs+n...],mu)
putobjsense(task,MSK_OBJECTIVE_SENSE_MAXIMIZE)
optimize(task)
# Check if the interior point solution is an optimal point
if getsolsta(task, MSK_SOL_ITR) != MSK_SOL_STA_OPTIMAL
# See https://docs.mosek.com/latest/juliaapi/accessing-solution.html about handling solution statuses.
error("Solution not optimal")
end
# Display solution summary for quick inspection of results
solutionsummary(task,MSK_STREAM_LOG)
writedata(task,"portfolio_3_impact.ptf");
# Read the results
xx = getxxslice(task,MSK_SOL_ITR, x_ofs+1,x_ofs+n+1)
expret = mu' * xx
(xx,expret)
end
end # portfolio()
Note that in the following part of the code:
let dom = appendprimalpowerconedomain(task,3,[2.0,1.0])
afei = getnumafe(task)
acci = getnumacc(task)
afe0 = afei
appendafes(task,2*n+1)
putafeg(task,afe0+1,1.0)
afei += 1
for i in 1:n
putafefentry(task,afei + i, c_ofs + i, 1.0);
putafefentry(task,afei + n + i, z_ofs + i, 1.0);
end
accafes = Int64[ k for i in 1:n for k in [ afei + i, afe0+1, afei + n + i ] ]
accb = zeros(n*3)
accdom = Int64[ dom for i in 1:n ]
appendaccs(task,accdom,accafes,accb)
for i in 1:n
putaccname(task,acci+i,"market_impact[$i]")
end
end
we create a sequence of power cones of the form \((t_k, 1, x_k-x_k^0)\in \POW_3^{2/3,1/3}\). The power cones are determined by the sequence of exponents \((2,1)\); we create a single domain to account for that.
Moreover, note that the second coordinate of all these affine conic constraints is the same affine expression equal to \(1\), and we use the feature that allows us to define this affine expression only once (as AFE number aoff_pow + 2 * n) and reuse it in all the ACCs.
11.1.6 Transaction Costs¶
Now assume there is a cost associated with trading asset \(j\) given by
Hence, whenever asset \(j\) is traded we pay a fixed setup cost \(f_j\) and a variable cost of \(g_j\) per unit traded. Given the assumptions about transaction costs in this section problem (11.6) may be formulated as
(11.11)¶\[\begin{split}\begin{array}{lrcll} \mbox{maximize} & \mu^T x & & &\\ \mbox{subject to} & e^T x + f^Ty + g^T z & = & w + e^T x^0, &\\ & (\gamma,G^T x) & \in & \Q^{k+1}, & \\ & z_j & \geq & x_j - x_j^0, & j=1,\ldots,n,\\ & z_j & \geq & x_j^0 - x_j, & j=1,\ldots,n,\\ & z_j & \leq & U_j y_j, & j=1,\ldots,n,\\ & y_j & \in & \{0,1\}, & j=1,\ldots,n, \\ & x & \geq & 0. & \end{array}\end{split}\]
First observe that
We choose \(U_j\) as some a priori upper bound on the amount of trading in asset \(j\) and therefore if \(z_j>0\) then \(y_j = 1\) has to be the case. This implies that the transaction cost for asset \(j\) is given by
Example code
The following example code demonstrates how to compute an optimal portfolio when transaction costs are included.
function portfolio( mu :: Vector{Float64},
x0 :: Vector{Float64},
w :: Float64,
gamma :: Float64,
GT :: Array{Float64,2},
f :: Vector{Float64},
g :: Vector{Float64})
(k,n) = size(GT)
maketask() do task
# Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
# Directs the log task stream
putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))
totalBudget = sum(x0)+w
#Offset of variables into the API variable.
x_ofs = 0
y_ofs = n
z_ofs = 2*n
# Constraints offsets
# Holding variable x of length n
# No other auxiliary variables are needed in this formulation
appendvars(task,3*n)
# Setting up variable x
for j in 1:n
# Optionally we can give the variables names
putvarname(task, x_ofs+j, "x[$(j)]");
putvarname(task, z_ofs+j, "z[$(j)]");
putvarname(task, y_ofs+j, "y[$(j)]");
# No short-selling - x^l = 0, x^u = inf
putvartype(task, y_ofs+j, MSK_VAR_TYPE_INT);
end
putvarboundsliceconst(task,x_ofs+1,x_ofs+n+1, MSK_BK_LO, 0.0, Inf);
putvarboundsliceconst(task,y_ofs+1,y_ofs+n+1, MSK_BK_RA, 0.0, 1.0);
putvarboundsliceconst(task,z_ofs+1,z_ofs+n+1, MSK_BK_FR, -Inf, Inf);
# One linear constraint: total budget
let coni = getnumcon(task)
appendcons(task,1);
putconname(task,coni+1,"budget")
consub = Int32[ coni+1 for i in 1:n ]
putaijlist(task,consub,[x_ofs+1:x_ofs+n...], ones(n))
putaijlist(task,consub,[z_ofs+1:z_ofs+n...],g)
putaijlist(task,consub,[y_ofs+1:y_ofs+n...],f)
putconbound(task, coni+1, MSK_BK_FX, totalBudget, totalBudget)
end
let coni = getnumcon(task)
appendcons(task,2*n)
for i in 1:n
putconname(task,coni+i,"zabs1[$i]")
putconname(task,coni+n+i,"zabs2[$i]")
putaij(task,coni + i, x_ofs + i, -1.0)
putaij(task,coni + i, z_ofs + i, 1.0)
putconbound(task,coni + i, MSK_BK_LO, -x0[i], Inf)
putaij(task,coni + n + i, x_ofs + i, 1.0)
putaij(task,coni + n + i, z_ofs + i, 1.0)
putconbound(task,coni + n + i, MSK_BK_LO, x0[i], Inf)
end
end
# - Switch
let coni = getnumcon(task)
appendcons(task,n)
for i in 1:n
putconname(task,coni+i, "switch[$i]")
putaij(task,coni + i, z_ofs + i, 1.0)
putaij(task,coni + i, y_ofs + i, -totalBudget)
putconbound(task,coni + i, MSK_BK_UP, -Inf, 0.0)
end
end
let afei = getnumafe(task),
acci = getnumacc(task)
# Input (gamma, GTx) in the AFE (affine expression) storage
# We need k+1 rows
appendafes(task,k + 1)
# The first affine expression = gamma
putafeg(task,afei+1, gamma)
# The remaining k expressions comprise GT*x, we add them row by row
# In more realisic scenarios it would be better to extract nonzeros and input in sparse form
subj = [1:n...]
for i in 1:k
putafefrow(task,afei+i+1, subj, GT[i,:])
end
# Input the affine conic constraint (gamma, GT*x) \in QCone
# Add the quadratic domain of dimension k+1
qdom = appendquadraticconedomain(task,k + 1)
# Add the constraint
appendaccseq(task,qdom,1,nothing)
putaccname(task,acci+1, "risk")
end
# Objective: maximize expected return mu^T x
putclist(task,[x_ofs+1:x_ofs+n...],mu)
putobjsense(task,MSK_OBJECTIVE_SENSE_MAXIMIZE)
optimize(task)
# Check if the integer solution is an optimal point
if getsolsta(task, MSK_SOL_ITG) != MSK_SOL_STA_INTEGER_OPTIMAL
# See https://docs.mosek.com/latest/juliaapi/accessing-solution.html about handling solution statuses.
error("Solution not optimal")
end
writedata(task,"portfolio_4_transcost.ptf")
# Display solution summary for quick inspection of results
solutionsummary(task,MSK_STREAM_LOG)
writedata(task,"portfolio_4_transcost.ptf");
# Read the results
xx = getxxslice(task,MSK_SOL_ITG, x_ofs+1,x_ofs+n+1)
expret = mu' * xx
(xx,expret)
end
end # portfolio()
11.1.7 Cardinality constraints¶
Another method to reduce costs involved with processing transactions is to only change positions in a small number of assets. In other words, at most \(K\) of the differences \(|\Delta x_j|=|x_j - x_j^0|\) are allowed to be non-zero, where \(K\) is (much) smaller than the total number of assets \(n\).
This type of constraint can be again modeled by introducing a binary variable \(y_j\) which indicates if \(\Delta x_j\neq 0\) and bounding the sum of \(y_j\). The basic Markowitz model then gets updated as follows:
(11.12)¶\[\begin{split}\begin{array}{lrcll} \mbox{maximize} & \mu^T x & & &\\ \mbox{subject to} & e^T x & = & w + e^T x^0, &\\ & (\gamma,G^T x) & \in & \Q^{k+1}, & \\ & z_j & \geq & x_j - x_j^0, & j=1,\ldots,n,\\ & z_j & \geq & x_j^0 - x_j, & j=1,\ldots,n,\\ & z_j & \leq & U_j y_j, & j=1,\ldots,n,\\ & y_j & \in & \{0,1\}, & j=1,\ldots,n, \\ & e^T y & \leq & K, & \\ & x & \geq & 0, & \end{array}\end{split}\]
were \(U_j\) is some a priori chosen upper bound on the amount of trading in asset \(j\).
Example code
The following example code demonstrates how to compute an optimal portfolio with cardinality bounds.
function portfolio( mu :: Vector{Float64},
x0 :: Vector{Float64},
w :: Float64,
gamma :: Float64,
GT :: Array{Float64,2},
K :: Int)
(k,n) = size(GT)
maketask() do task
# Use remote server: putoptserverhost(task,"http://solve.mosek.com:30080")
# Directs the log task stream
# putstreamfunc(task,MSK_STREAM_LOG,msg -> print(msg))
totalBudget = sum(x0)+w
#Offset of variables into the API variable.
x_ofs = 0
y_ofs = n
z_ofs = 2*n
# Constraints offsets
# Holding variable x of length n
# No other auxiliary variables are needed in this formulation
appendvars(task,3*n)
# Setting up variable x
for j in 1:n
# Optionally we can give the variables names
putvarname(task, x_ofs+j, "x[$(j)]");
putvarname(task, y_ofs+j, "y[$(j)]");
putvarname(task, z_ofs+j, "z[$(j)]");
putvartype(task, y_ofs+j, MSK_VAR_TYPE_INT);
end
# No short-selling - x^l = 0, x^u = inf
putvarboundsliceconst(task,x_ofs+1,x_ofs+n+1, MSK_BK_LO, 0.0, Inf);
putvarboundsliceconst(task,y_ofs+1,y_ofs+n+1, MSK_BK_RA, 0.0, 1.0);
putvarboundsliceconst(task,z_ofs+1,z_ofs+n+1, MSK_BK_FR, -Inf, Inf);
# One linear constraint: total budget
let coni = getnumcon(task)
appendcons(task,1);
putconname(task,coni+1,"budget")
consub = Int32[ coni+1 for i in 1:n ]
putaijlist(task,consub,[x_ofs+1:x_ofs+n...], ones(n))
putconbound(task, coni+1, MSK_BK_FX, totalBudget, totalBudget)
end
let coni = getnumcon(task)
appendcons(task,1)
putarow(task,coni+1,[y_ofs+1:y_ofs+1+n...],ones(n));
putconbound(task,coni+1,MSK_BK_UP, 0.0, K)
putconname(task,coni+1,"cardinality")
end
let coni = getnumcon(task)
appendcons(task,2*n)
for i in 1:n
putconname(task,coni+i,"zabs1[$i]")
putconname(task,coni+n+i,"zabs2[$i]")
putaij(task,coni + i, x_ofs + i, -1.0)
putaij(task,coni + i, z_ofs + i, 1.0)
putconbound(task,coni + i, MSK_BK_LO, -x0[i], Inf)
putaij(task,coni + n + i, x_ofs + i, 1.0)
putaij(task,coni + n + i, z_ofs + i, 1.0)
putconbound(task,coni + n + i, MSK_BK_LO, x0[i], Inf)
end
end
# - Switch
let coni = getnumcon(task)
appendcons(task,n)
for i in 1:n
putconname(task,coni+i, "switch[$i]")
putaij(task,coni + i, z_ofs + i, 1.0)
putaij(task,coni + i, y_ofs + i, -totalBudget)
putconbound(task,coni + i, MSK_BK_UP, -Inf, 0.0)
end
end
let afei = getnumafe(task),
acci = getnumacc(task)
# Input (gamma, GTx) in the AFE (affine expression) storage
# We need k+1 rows
appendafes(task,k + 1)
# The first affine expression = gamma
putafeg(task,afei+1, gamma)
# The remaining k expressions comprise GT*x, we add them row by row
# In more realisic scenarios it would be better to extract nonzeros and input in sparse form
subj = [1:n...]
for i in 1:k
putafefrow(task,afei+i+1, subj, GT[i,:])
end
# Input the affine conic constraint (gamma, GT*x) \in QCone
# Add the quadratic domain of dimension k+1
qdom = appendquadraticconedomain(task,k + 1)
# Add the constraint
appendaccseq(task,qdom,1,nothing)
putaccname(task,acci+1, "risk")
end
# Objective: maximize expected return mu^T x
putclist(task,[x_ofs+1:x_ofs+n...],mu)
putobjsense(task,MSK_OBJECTIVE_SENSE_MAXIMIZE)
optimize(task)
if getsolsta(task, MSK_SOL_ITG) != MSK_SOL_STA_INTEGER_OPTIMAL
# See https://docs.mosek.com/latest/juliaapi/accessing-solution.html about handling solution statuses.
error("Solution not optimal")
end
# Display solution summary for quick inspection of results
solutionsummary(task,MSK_STREAM_LOG)
writedata(task,"portfolio_5_card-$K.ptf");
# Read the results
xx = getxxslice(task,MSK_SOL_ITG, x_ofs+1,x_ofs+n+1)
expret = mu' * xx
(xx,expret)
end
end # portfolio()
If we solve our running example with \(K=1,\dots,n\) then we get the following solutions, with increasing expected returns:
Bound 1 Solution: 0.0000e+00 0.0000e+00 1.0000e+00 0.0000e+00 0.0000e+00 0.0000e+00 0.0000e+00 0.0000e+00
Bound 2 Solution: 0.0000e+00 0.0000e+00 3.5691e-01 0.0000e+00 0.0000e+00 6.4309e-01 -0.0000e+00 0.0000e+00
Bound 3 Solution: 0.0000e+00 0.0000e+00 1.9258e-01 0.0000e+00 0.0000e+00 5.4592e-01 2.6150e-01 0.0000e+00
Bound 4 Solution: 0.0000e+00 0.0000e+00 2.0391e-01 0.0000e+00 6.7098e-02 4.9181e-01 2.3718e-01 0.0000e+00
Bound 5 Solution: 0.0000e+00 3.1970e-02 1.7028e-01 0.0000e+00 7.0741e-02 4.9551e-01 2.3150e-01 0.0000e+00
Bound 6 Solution: 0.0000e+00 3.1970e-02 1.7028e-01 0.0000e+00 7.0740e-02 4.9551e-01 2.3150e-01 0.0000e+00
Bound 7 Solution: 0.0000e+00 3.1970e-02 1.7028e-01 0.0000e+00 7.0740e-02 4.9551e-01 2.3150e-01 0.0000e+00
Bound 8 Solution: 1.9557e-10 2.6992e-02 1.6706e-01 2.9676e-10 7.1245e-02 4.9559e-01 2.2943e-01 9.6905e-03
